WinWedge와  Excel의 연결-2

Excel의 작업표 상의 버튼에 편입된 매크로에 의하여，계측 기기를 제어하고 데이터 읽어들이는 방법을 기술합니다．

1. WinWedge의 설정

데이터 읽어들이기를 한 계측 기기의 통신 사양 및 입력 데이터 구조에 준하여，WinWedge의 설정 파일을 작성합니다．이 샘플으로 아래와 같은 데이터를 상정하고 작업을 진행합니다．("WinWedge와 Excel의 연결-1"의 설정과 동일합니다)

위 내용으로 설정한 파일을 여기에서는，"MyConfig.SW3"라는 명칭으로 ，WinWedge가 설치되어있는 폴더 내(디폴트로는 C:/Program Files/WinWedge 32)에 보존합니다．

2. Excel 2000의 설정

Excel을 시동하고，툴 메뉴로부터 매크로:Visual Basic Editor을 시동합니다．삽입 메뉴로부터"표준 모듈"을 선택하고，표시된 코드 윈도우에 아래와 같은 코드를 카피하고, 페이스트합니다．(코멘트를 참고하여，자신의 환경에 맞도록 수정하여 주세요) 또한，이 페이지의 말미에서 하기 매크로를 포함한 Excel 파일을 다운 로드 받을 수 있기 때문에，이쪽도 이용하십시오.

Global RowPtr As Long, ColPtr As Long
Global Const MyPort = "COM1" 'COM 포트 번호는 이용 환경에 합쳐서 변경하십시오．
Global Const CmdLine = "C:\Program Files\WinWedge 32\WinWedge.Exe C:\Program Files\WinWedge 32\MyConfig.SW3"
'WinWedge 및 설정 파일의 커맨드 라인은 각자 보존하고 있는 풀 패스를 기술하십시오．

Sub WedgeStart()
On Error Resume Next '에러를 무시하고 WinWedge를 시동합니다．
RetVal = Shell(CmdLine) '위의 커맨드 라인으로 WinWedge를 시동합니다．
  If RetVal = 0 Then 'WinWedge가 발견되지 않는 경우，에러를 표시합니다．
Beep: MsgBox ("파일 이름 WinWedge.Exe가 발견되지 않습니다") '에러 메시지를 표시
  Exit Sub   '매크로의 종료
  End If   'WinWedge가 발견되면
  Application.Wait Now + 0.00002 '시동에 필요로 한 시간을 줍니다．
  AppActivate Application.Caption '그 후，Excel에 포커스를 되돌립니다．
End Sub

Sub DataStart()
  chan = DDEInitiate("WinWedge", MyPort) 'WinWedge와 DDE 링크를 확립합니다．
  DDEExecute chan, "[SENDOUT('S')]"
'데이터 송출의 트리거로 된 문자 열S를 시리얼 포트에 송출하고，데이터 읽어들이기를 개시합니다．
  DDETerminate chan  'DDE 링크를 단절합니다．
  Application.Wait Now + 0.000012 '계측 기기로부터 데이터 출력된 여유를 줍니다．
StartCollecting   '서브루틴"StartCollecting"을 실행합니다．
End Sub

Sub StartCollecting()
  RowPtr = 1: ColPtr = 1 '변수 RowPtr，ColPtr을 초기화합니다．
  Worksheets("Sheet1").Activate   'Sheet1을 액티브화 합니다．
  Worksheets("Sheet1").Cells(1, 50).Formula = "=WinWedge|" & MyPort & "!      RecordNumber" 'Sheet1의 셀(1,50)과 WinWedge와의 링크를 확립합니다．셀번지는 필요
에 따라서 변경 가능합니다．여기에서는 실제의 데이터를 받아 들이는 것에 영향이 없는 위치에 설정합니다.
  ActiveWorkbook.SetLinkOnData "WinWedge|" & MyPort & "!RecordNumber", "GetSWData"
' SetLinkData 방법에 의하고，서브루틴"GetSWData"를 실행합니다．
End Sub

Sub Auto_Close()   'Excel 연습 문제집을 닫는다면 자동적으로 실행됩니다．
  StopCollecting   '서브루틴"StopCollecting"를 실행합니다．
  On Error Resume Next   '에러를 무시하고 계속합니다．
  chan = DDEInitiate("WinWedge", MyPort)   'WinWedge와 DDE 링크를 확립합니다．
  DDEExecute chan, "[Appexit]"   'DDE 링크를 단절하고，DDE 커맨드[Appexit]에 의하여
WinWedge를 종료합니다．
End Sub

Sub StopCollecting()
Worksheets("Sheet1").Activate   'Sheet1을 액티브하게 합니다．
Worksheets("Sheet1").Cells(1, 50).Formula = ""  '셀(1,50)의 DDE 링크를 단절합니다．
ActiveWorkbook.SetLinkOnData "WinWedge|" & MyPort & "!RecordNumber", ""  ' 빈 문자열(" ")을 매크로 이름에 배당 SetLinkOnData 방법의 기능을 정지합니다．
End Sub

Sub GetSWData()
  chan = DDEInitiate("WinWedge", MyPort)  'WinWedge와 DDE 링크를 확립합니다．
  MyVariantArray = DDERequest(chan, "Field(1)")  'WinWedge의 필드 1으로부터 데이터를 취득
  MyString$ = MyVariantArray(1)  '문자열로 변환
  Worksheets("Sheet1").Cells(RowPtr, ColPtr).Formula = MyString$
'시트 1의 셀 어드레스(RowPtr,ColPtr)에 데이터를 입력합니다．
'Excel의 함수 DDERequest는 데이터를 변형 형태의 배열으로서 취득합니다．이것은 말하자면，'Excel의 습성이라고 이해하십시오．그러나，데이터를 셀에 거두어들인 때는 문자열형이 아니면 않되기 때문에，위의 행으로 변형형 배열의 요소를 문자열로 변환하고 있습니다．거두어들였던 데이터에 어떠한 처리를 실행한 경우에는，여기에 프로그램을 기술합니다．

'필드 2 이후의 데이터도 거두어들인 경우에는 아래와 같이 기술합니다．(이하는 필드 3까지의 받아들이기)
  MyVariantArray = DDERequest(chan, "Field(2)")   'WinWedge의 필드 2로부터 데이터를 취득
  MyString$ = MyVariantArray(1)   '문자열로 변환
  Worksheets("Sheet1").Cells(RowPtr, ColPtr + 1).Formula = MyString$
  MyVariantArray = DDERequest(chan, "Field(3)")  'WinWedge의 필드 3으로부터 데이터를 취득
  MyString$ = MyVariantArray(1)   '문자열로 변환
  Worksheets("Sheet1").Cells(RowPtr, ColPtr + 2).Formula = MyString$

  DDETerminate chan  'DDE 링크를 단절합니다．
  RowPtr = RowPtr + 1  '행 포인터를 아래의 행에 이동합니다．
End Sub

Sub StopData()
chan = DDEInitiate("WinWedge", MyPort)   'WinWedge와 DDE 링크를 확립
DDEExecute chan, "[SENDOUT('E')]"
'문자 E를 시리얼 포트에 송출하고，데이터 송출을 중단합니다．이 이용의 계측 기기의 사양에 합쳐서 E의 위치에 문자 열등을 입력합니다．
DDETerminate chan   'DDE 링크를 단절합니다．
End Sub

Sub Restart()
  chan = DDEInitiate("WinWedge", MyPort)   'WinWedge와 DDE 링크를 확립
  DDEExecute chan,   "[SENDOUT('S')]" '시리얼 포트에 문자 S를 송출하고，데이터 송출을 재개합니다．
  DDETerminate chan   'DDE 링크를 단절합니다．
End Sub

Sub DataClear()
  Columns("A:C").Select 'A 열로부터 C 열을 선택
  Selection.ClearContents '선택한 범위를 소거
  Worksheets("Sheet1").Range("A1").Select '셀 A1을 선택합니다．
End Sub

마지막으로 Excel의 표시 메뉴로부터 ”툴 바:폼”를 선택하고，폼 다이어 로그 박스로부터 "버튼"을 선택하고，작업표 상에 버튼을 작성하고，각각에 위 매크로를 등록합니다．
샘플 Excel 파일은 아래에서부터 다운 로드 받을 수 있습니다．

샘플 파일의 다운 로드 （43.5KB)
*Excel97/2000로 동작 확인을 했습니다．
*자기 해동 형식의 압축 파일입니다．더블 클릭하고 해동하십시오.
 

EXIT

Copyright  © 2001 ArmTech System Inc. All rights reserved.
armtech@sciencesoftware.co.kr